Developing Java applications with Emacs using Nix

I want:

• Per-directory Java development environments
• Acceptable LSP support in Emacs, which includes at a minimum:
  • Autocomplete method names
  • Autocomplete class names from packages that haven't been imported + auto-import when selected
  • Jump to definition
  • Documentation on hover
• Maven integration – the LSP should be aware of all maven dependencies.
• All packages managed by nix to ensure reproducibility.

In my experience, searching around for advice doing this turns up many people recommending that I use some JetBrains product for writing Java code and skipping the DIY route of cobbling together editors and LSP servers. To them, I say: "You're probably right and wiser than I am, but thanks for nothing."

I searched around for "emacs java nix" and found this blog post. I used that post as a starting point for this one. Thank you Dominik!

The main thing I wanted over that example is that I want to be able to copy/paste some files into an existing maven project and immediately open a java file and in emacs run M-x lsp. I want each project to have separate jdtls workspaces, and its own independent set of maven dependencies.

All of the advice in Dominik's post about overriding lsp-java--server-ls still applies since lsp-java's invocation is probably out of date, but with some slight modifications.

These are the things I'm using to set up the development environment. This doesn't include the JDK, JRE, and Maven.

• nix
• direnv – direnv lets you have per-directory environments. This usually amounts to setting environment variables when entering a directory and unsetting them when leaving that directory.
  • nix-direnv – lets you use a nix flake
• emacs
  • envrc-mode – emacs' per-buffer direnv integration
  • lsp-mode
  • lsp-java – lsp-mode integration with jdtls
• jdtls – the LSP for Java (originally made for Eclipse)

package.nix contains the actual package definition.

There's nothing special about this, and it just uses the nixpkgs-provided buildMavenPackage function.

package.nix:

{
  makeWrapper,
  maven,
  nix-gitignore,
  jre,
}:
let
  jarName = "sample-HEAD-SNAPSHOT.jar";
in
maven.buildMavenPackage rec {
  pname = "myMavenProject";
  version = "0.9.3";

  src = nix-gitignore.gitignoreSource [ "*.nix" ] ./.;

  mvnHash = "sha256-AL9iHDu2gz/JhEx8OUDodORITdEZuoOfT4QtbDy8T7E=";
  nativeBuildInputs = [ makeWrapper ];
  installPhase = ''
    mkdir -p $out/bin $out/share/${pname}
    install -Dm644 target/${jarName} $out/share/${pname}

    makeWrapper ${jre}/bin/java $out/bin/${pname} \
      --add-flags "-jar $out/share/${pname}/${jarName}"
  '';
}

shell.nix contains the definition of the development shell.

One might wonder why the shellHook needs to copy all of the maven dependencies into a temporary directory and not instead simply set the environment variables to point to the nix store. The reason for this is that jdtls expects the directory to be writable, and the nix store is read-only.

shell.nix:

{
  pkgs ? import (builtins.getFlake "nixpkgs") { system = builtins.currentSystem; },
  mvnDeps ? (pkgs.callPackage ./package.nix { }).fetchedMavenDeps,
}:
pkgs.mkShell {
  packages = with pkgs; [
    jdk11_headless
    jdt-language-server
    maven
  ];

  # Initialize .jdtls directory with stuff that jdt-language-server
  # needs. The directory should probably be added to .git/info/exclude
  # (or equivalent) of the enclosing project.
  shellHook = ''
    export TMPDIR=$PWD/.jdtls

    rm -rf $TMPDIR/
    mkdir -p $TMPDIR/{maven,config,workspace}

    # Copy maven repository into jdtls directory
    cp -dpR ${mvnDeps}/.m2 $TMPDIR/maven/
    export MAVEN_OPTS="-Dmaven.repo.local=$TMPDIR/maven/.m2"

    # Copy config into jdtls directory
    cp -dpR ${pkgs.jdt-language-server}/share/java/jdtls/config_linux $TMPDIR/config/
    export JDTLS_CONFIG="$TMPDIR/config/config_linux"

    # Set the workspace
    export JDTLS_WORKSPACE="$TMPDIR/workspace"

    # Mark everything writable to keep jdtls happy
    chmod +w -R $TMPDIR
  '';
}

This sets everything up in the working directory. If that's not desirable, the first line of the shellHook can be replaced with export TMPDIR=/tmp/javalsp/${PWD//\//_} – this will create a unique directory under /tmp/ for each project.

I use direnv (and nix-direnv) paired with envrc-mode to get Emacs to pick up the shell environment. That's how I pass the environment variables JDTLS_CONFIG and JDTLS_WORKSPACE to jdtls.

$ echo use_flake > .envrc
$ direnv allow